ansys讀入和寫出數(shù)據(jù)文件并實(shí)現(xiàn)多載荷步瞬態(tài)動(dòng)力學(xué)求解例子

2017-03-03 by:CAE仿真在線來(lái)源:互聯(lián)網(wǎng)

一根半徑為0.1m長(zhǎng)度為10m的圓柱桿直立在地面上,下端完全固定,現(xiàn)在記錄有0~10s之間每隔1s時(shí)候上部端點(diǎn)的水平作用力大小

,并按時(shí)間已經(jīng)記錄在數(shù)據(jù)文件ftop.dat中。計(jì)算圓柱桿的動(dòng)態(tài)響應(yīng),提取頂點(diǎn)在激勵(lì)方向上水平位移并存入數(shù)據(jù)文件utop.dat

中。

首先創(chuàng)建ftop.dat文件并存放在ansys的當(dāng)前目錄下,其包含的數(shù)據(jù)內(nèi)容如下:(第一列數(shù)據(jù)占3個(gè)字符寬度,第二列數(shù)據(jù)占11個(gè)

字符寬度)
1 1600
2 7000
3 15000
4 5000
5 500
6 -2000
7 -800
8 1800
9 200
10 -3400

命令流:

*create,byb,mac
finish
/clear

*dim,ftop,,10,2
*vread,ftop(1,1),ftop,dat,,jik,2,10
(f3.0,f11.0)
!按指定格式輸入數(shù)據(jù)
/prep7
et,1,beam189

sectype,1,beam,csolid,cir-sect,0
secoffset,cent
secdata,0.1
!定義梁189的截面號(hào)1
mp,ex,1,2e11
mp,nuxy,1,0.3
mp,dens,1,7800
!定義材料
/view,1,1,1,1
/ang,1
!調(diào)整圖形為等視圖顯示
k,1
k,2,,,10
k,3,1
lstr,1,2
latt,1,,1,,3,,1
!給線分配單元屬性:mat=1,type=1,方向kp=3
esize,1,0
lmesh,1

/eshape,1
!打開(kāi)單元截面形狀顯示開(kāi)關(guān)
eplot

dk,1,all,0
save
finish
!執(zhí)行瞬態(tài)分析的循環(huán)求解過(guò)程
/solu
antype,4
!選擇瞬態(tài)分析類型
trnopt,full
!選擇瞬態(tài)完全法
nlgeom,1
!打開(kāi)幾何打變形開(kāi)關(guān)
outres,all,all
!求解輸入所有子步的所有結(jié)果項(xiàng)到結(jié)果文件中
autots,0
!關(guān)閉自動(dòng)調(diào)整載荷長(zhǎng)功能
kbc,0
!采用漸變載荷加載方式
*do,i,1,10
!執(zhí)行10次循環(huán)加載
time,ftop(i,1)
!設(shè)置當(dāng)前載荷步終點(diǎn)時(shí)間
nsubst,10,0,0
!設(shè)置當(dāng)前載荷步中的子步數(shù)目

fk,2,fx,ftop(i,2)
!施加當(dāng)前載荷步的終點(diǎn)載荷
solve
*enddo
finish

/post26
ntop=node(0,0,10)
!利用node(x,y,z)提取頂點(diǎn)位置上的節(jié)點(diǎn)編號(hào)
nsol,2,ntop,u,x,ux_top
!定義頂點(diǎn)位置節(jié)點(diǎn)的位移UX(T)記錄變量2
xvar,1
!時(shí)間記錄變量1作為X軸映射變量
plvar,2
!繪制頂節(jié)點(diǎn)位移UX(T)記錄變量2曲線

!創(chuàng)建二維數(shù)組utop(100,2)用時(shí)間序列及其對(duì)應(yīng)位移填充它
*dim,utop,,100,2
!用時(shí)間序列填充數(shù)組utop(100,2)的第一列
*vfill,utop(1,1),ramp,0.1,0.1
!用位移響應(yīng)ux序列填充數(shù)組utop(100,2)的第二列
vget,utop(1,2),2,0.1

!將二維數(shù)組utop(100,2)的數(shù)據(jù)寫入文件utop.dat中
*cfopen,utop,dat,,
*do,i,1,100,1
*vwrite,utop(i,1),utop(i,2)
(f3.1,' ',f15.12)
!按格式將當(dāng)前行數(shù)據(jù)寫入utop.dat中
*enddo
*cfclose
*end
byb

開(kāi)放分享：優(yōu)質(zhì)有限元技術(shù)文章,助你自學(xué)成才